子模型應(yīng)用實例（shell-to-solid）

2017-03-02 by:CAE仿真在線來源:互聯(lián)網(wǎng)

!第一步總體模型建模及其分析求解
FINISH
/CLEAR,START
/FILNAM,FULL-MODEL
/TITLE,FULL,MODEL,SOLUTION

/PREP7
ET,1,SHELL63
R,1,0.02

MP,EX,1,2E11
MP,PRXY,1,0.3

RECTNG,0,1,0,0.1,
CYL4,0.5,0.05,0.02
ASBA,1,2

AATT,1,1,1,0,
ESIZE,0.03,0,
MSHAPE,0,2D
MSHKEY,0
AMESH,ALL
FINISH

/SOLU
ANTYPE,0
LSEL,S,LOC,X,0
DL,ALL,,ALL,

LSEL,S,LOC,Y,0.1
SFL,ALL,PRES,40,

LSEL,S,LOC,X,1
SFL,ALL,PRES,-1.6E5,

ALLS
SAVE
SOLVE
FINISH

/POST1
SET,LAST
/EFACET,1

plnsol,s,eqv,0,1.0

!第二步,子模型建模,定義切割邊界節(jié)點文件
finisN
/FILNAM,SUBMODELING
/TITLE,SUBMODELING,SOLUTION

/PREP7
ACLEAR,ALL
CM,A1,AREA

ASEL,NONE
RECTNG,0,0.4,0,0.1
RECTNG,0.6,1,0,0.1
CM,A2,AREA
ALLS
ASBA,A1,A2
CM,A1,AREA

VEXT,A1,,,0,0,0.01
VEXT,A1,,,0,0,-0.01

ETDEL,1
ET,1,SOLID185
AATT,1,1,1,0
ESIZE,0.004,0,
VSWEEP,ALL

!第三步選擇出切割邊界節(jié)點,寫進(jìn)節(jié)點文件CUT-BC.node
NSEL,S,LOC,X,0.4
NSEL,A,LOC,X,0.6
NPLOT
!寫出子模型切割邊界上的節(jié)點文件
NWRITE,'CUT-BC','NODE',' ',0

ALLS
SAVE
FINISH

!第四步調(diào)入總體模型,將總體模型的位移結(jié)果插值到子模型的切割邊界節(jié)點上
/FILNAM,FULL-MODEL
RESUME
/POST1
FILE,'FULL-MODEL','RST','.'
SET,LAST

!寫出子模型切割邊界上的位移約束定義條件
CBDOF,'CUT-BC','NODE','','U-CUT-BC','CBDO','',0,START,1
FINISH

!第五步調(diào)入子模型,首先進(jìn)入前處理器讀入切割邊界旋轉(zhuǎn)角定義,
!然后,進(jìn)入求解器讀入切割邊界節(jié)點位移定義,并將其他載荷施加
!到子模型上,最后進(jìn)行子模型求解
/FILNAM,SUBMODELING
RESUME
/PREP7
!修正子模型切割邊界節(jié)點的旋轉(zhuǎn)角
/INPUT,'U-CUT-BC','CBDO','',,0
EPLOT
FINISH

/SOL
ANTYPE,0
!施加切割邊界位移約束
/INPUT,'U-CUT-BC','CBDO','',:START,0

ASEL,S,LOC,Y,0.1
SFA,ALL,1,PRES,2E3!施加上表面壓力

ALLS
SAVE
SOLVE
FINISH

/POST1
SET,LAST
/EFACET,1
PLNSOL,S,EQV,0,1.0

開放分享：優(yōu)質(zhì)有限元技術(shù)文章,助你自學(xué)成才