搜索ANSYS流固耦合實(shí)例
2017-03-03 by:CAE仿真在線 來源:互聯(lián)網(wǎng)
發(fā)一個(gè)流固耦合的例子,希望對(duì)正在學(xué)流體分析的有幫助
換熱器分析:
換熱器由兩種成份構(gòu)成,采用逆流。由一個(gè)固體隔開。
分兩步求解:
第一步只進(jìn)行流體分析,第二步進(jìn)行溫度分析。
fini
/filname,Exercise17 ! 定義CFD分析文件名
/prep7 ! 進(jìn)入前處理器
LX = 10
NDX = 10
LY1 = 2
LY2 = 0.1
LY3 = 1.0
NDY1 = 10
NDY2 = 3
NDY3 = 10
YOFFSET = 0 ! 定義各參數(shù)
et,1,141 ! 選擇單元
keyopt,1,1,2 ! 將流體設(shè)置為兩組分
esha,2 ! 選擇平面劃分單元方式
rect,,LX,YOFFSET,YOFFSET+LY1 ! 建立流體區(qū)域1的幾何模型
rect,,LX,YOFFSET+LY1,YOFFSET+LY1+LY2 ! 建立固體區(qū)域的幾何模型
rect,,LX,YOFFSET+LY1+LY2,YOFFSET+LY1+LY2+LY3 ! 建立流體區(qū)域2的幾何模型
nummrg,all ! 合并關(guān)鍵點(diǎn)
numcmp,all ! 壓縮編號(hào)
lsel,s,,,3,9,3
lsel,a,,,1
lesi,all,,,NDX, ! 劃分橫向各直線的單元密度
lsel,s,,,2,4,2
lesi,all,,,NDY1,-5.0 ! 劃分流體區(qū)域1豎向各直線的單元密度
lsel,s,,,5,7,2
lesi,all,,,NDY2,-5.0 ! 劃分固體區(qū)域豎向各直線的單元密度
lsel,s,,,8,10,2
lesi,all,,,NDY3,-5.0 ! 劃分流體區(qū)域2豎向各直線的單元密度
allsel,all
mat,1 ! 定義流體材料號(hào)
amesh,1 ! 劃分流體區(qū)域1的單元
amesh,3 ! 劃分流體區(qū)域2的單元
mat,2 ! 定義固體材料號(hào)
amesh,2 ! 劃分固體區(qū)域的單元密度
!inner region 1 ! 定義流體區(qū)域1的邊界條件
!bc inlet ! 定義流體區(qū)域1進(jìn)口邊界條件
lsel,s,,,4
nsll,s,1
d,all,pres,10 ! 定義流體區(qū)域1進(jìn)口壓力邊界條件
d,all,temp,100 ! 定義流體區(qū)域1溫度邊界條件
!bc outlet ! 定義流體區(qū)域1出口邊界條件
lsel,s,,,2
nsll,s,1
d,all,pres,0 ! 定義流體區(qū)域1出口壓力邊界條件
!symm ! 定義對(duì)稱面約束條件
lsel,s,,,1
nsll,s,1
d,all,vy,0 ! 定義對(duì)稱面速度約束條件
!region 2 ! 定義流體區(qū)域2的邊界條件
!bc inlet ! 定義流體區(qū)域2進(jìn)口邊界條件
lsel,s,,,8
nsll,s,1
d,all,pres,10. ! 定義流體區(qū)域2進(jìn)口壓力邊界條件
d,all,temp,400 ! 定義流體區(qū)域2溫度邊界條件
!bc outlet ! 定義流體區(qū)域2出口邊界條件
lsel,s,,,10
nsll,s,1
d,all,pres,0. ! 定義流體區(qū)域2出口壓力邊界條件
!top wall ! 定義頂面的邊界約束條件
lsel,s,,,9
nsll,s,1
d,all,vx,0
d,all,vy,0 ! 定義頂面的速度約束邊界條件
allsel
!solid properties ! 定義固體的材料參數(shù)
mp,dens,2,5. ! 定義密度
mp,kxx,2,100 ! 定義熱傳導(dǎo)系數(shù)
mp,c,2,13 ! 定義比熱
/solu ! 進(jìn)入求解器
!ic for species ! 定義流體組分
nsel,s,loc,x,,lx
nsel,r,loc,y,0,ly1
ic,all,sp01,1.0
ic,all,sp02,0.0 ! 定義流體區(qū)域1材料組分
nsel,s,loc,x,,lx
nsel,r,loc,y,ly1+ly2,ly1+ly2+ly3
ic,all,sp01,0.0
ic,all,sp02,1.0 ! 定義流體區(qū)域2材料組分
allsel
! 第一步:進(jìn)行流體場(chǎng)分析
flda,iter,exec,200 ! 定義迭代次數(shù)
flda,prot,dens,cmix ! 定義流體密度
flda,prot,visc,cmix ! 定義流體粘度
flda,prot,cond,cmix ! 定義流體熱傳導(dǎo)系數(shù)
flda,prot,spht,cmix ! 定義流體比熱
flda,vary,dens,t
flda,vary,visc,t
flda,vary,cond,t
flda,vary,spht,t ! 定義流體各材料參數(shù)為變化的
flda,nomi,dens,1 ! 定義流體區(qū)域的初始密度
flda,nomi,visc,2 ! 定義流體區(qū)域的初始粘度
flda,nomi,cond,3 ! 定義流體區(qū)域的初始熱傳導(dǎo)系數(shù)
flda,nomi,spht,4 ! 定義流體區(qū)域的初始比熱
msprop,1,spht,constant,1 ! 定義流體1組分比熱
msprop,2,spht,constant,2 ! 定義流體2組分比熱
msprop,1,dens,constant,1 ! 定義流體1組分密度
msprop,2,dens,constant,2 ! 定義流體2組分密度
msprop,1,visc,constant,1.0 ! 定義流體1組分粘度
msprop,2,visc,constant,2.0 ! 定義流體2組分粘度
msprop,1,cond,constant,.1 ! 定義流體1組分熱傳導(dǎo)系數(shù)
msprop,2,cond,constant,.2 ! 定義流體2組分熱傳導(dǎo)系數(shù)
flda,conv,pres,1e-10
flda,term,pres,1e-9
flda,outp,sp01,t
flda,outp,sp02,t ! 定義流體場(chǎng)求解控制
solve ! 進(jìn)行流體場(chǎng)求解
/post1 ! 進(jìn)入通用后處理器
set,last ! 讀取最后載荷步的分析結(jié)果
plnsol,pres,,0, ! 顯示壓力分布云圖
plvect,v,,,,vect,elem,on,0 ! 顯示速度矢量分布圖
! 第二步:進(jìn)行溫度場(chǎng)求解
/solu ! 進(jìn)入求解器
flda,solu,enrg,t
flda,solu,flow,f
flda,meth,enrg,3
flda,iter,exec,50
flda,relx,temp,1 ! 定義溫度場(chǎng)求解控制
solve ! 進(jìn)行溫度場(chǎng)求解
/post1 ! 進(jìn)入通用后處理器
set,last ! 讀取最后載荷步的分析結(jié)果
plnsol, temp,,0, ! 顯示溫度分布云圖
fini
/exit,nosav ! 退出ANSYS
相關(guān)標(biāo)簽搜索：ANSYS流固耦合實(shí)例 Ansys有限元培訓(xùn) Ansys workbench培訓(xùn) ansys視頻教程 ansys workbench教程 ansys APDL經(jīng)典教程 ansys資料下載 ansys技術(shù)咨詢 ansys基礎(chǔ)知識(shí) ansys代做 Fluent、CFX流體分析 HFSS電磁分析 Abaqus培訓(xùn)
