搜索教育部CAE考試樣題-角架板變形和應(yīng)力ANSYS分析
2017-02-28 by:CAE仿真在線 來(lái)源:互聯(lián)網(wǎng)
導(dǎo)讀:掌握帶厚度的平面應(yīng)力模型的幾何建模和單元?jiǎng)澐诌^(guò)程,會(huì)靈活運(yùn)用各種坐標(biāo)系,板上施加的均布載荷數(shù)值單位是Pa或MPa。
一、問(wèn)題描述
圖示角架板的厚度為3.125mm,左側(cè)固定,上部受均布載荷作用,q=2601N/m。已知彈性模量E=200GPa,泊松比μ=0.3。分析研究角架的變形和應(yīng)力,求出節(jié)點(diǎn)的最大位移和最大Von Mises應(yīng)力(第4強(qiáng)度相當(dāng)應(yīng)力)。
問(wèn)題分析:帶厚度的板采用帶厚度的平面應(yīng)力單元建模,單元選用4節(jié)點(diǎn)的PLANE182或8節(jié)點(diǎn)的PLANE183。采用N、mm和MPa單位制。板上施加的均布載荷數(shù)值單位是Pa或MPa,均布載荷q=2601N/m,換成MPa為2.601/3.125。
計(jì)算結(jié)果
(1) x方向變形云圖,變形量-0.014mm~0.018mm。
(2) y方向變形云圖,變形量-0.128mm。
(3)總變形云圖,變形量0.128mm。
(4)第四強(qiáng)度相當(dāng)應(yīng)力云圖,應(yīng)力值45.9MPa。
二、GUI步驟
1.進(jìn)入ANSYS
程序→ ANSYS → ANSYS Product Launcher → 改變working directory到指定文件夾→ 在job name輸入:file → Run。
2.創(chuàng)建關(guān)鍵點(diǎn)
Main Menu>Preprocessor >Modeling >Create >Keypoints >In Active CS →依次輸入關(guān)鍵點(diǎn)的編號(hào)和坐標(biāo) →OK。默認(rèn)是直角坐標(biāo)系。
2.創(chuàng)建線
(1)創(chuàng)建圓弧線
①移動(dòng)工作平面:Utility Menu >WorkPlane >Offset WP to >Keypoints→拾取關(guān)鍵點(diǎn)K1和K3。
②創(chuàng)建局部坐標(biāo)系(柱坐標(biāo)系):Utility Menu >WorkPlane >Local Coordinate Systems >Create Local CS >At WP Origin →KCN:11;KCS:Cylindrical 1 →OK。
③切換當(dāng)前活動(dòng)坐標(biāo)系到局部坐標(biāo)系:UtilityMenu>WorkPlane>Change Active CS to>Specified Coord Sys → KCN:11 →OK。
④在當(dāng)前活動(dòng)坐標(biāo)系下創(chuàng)建線:Main Menu >Preprocessor >Modeling>Create >Lines >Lines >In Active Coord →拾取K1和K2 → Apply →拾取K2和K3→OK。當(dāng)前活動(dòng)坐標(biāo)系為柱坐標(biāo)系,創(chuàng)建的線為圓弧線。
⑤打開(kāi)關(guān)鍵點(diǎn)和線編號(hào):Utility Menu > PlotCtrls > Numbering→KP Keypoint numbers:ON;LINE Line numbers:ON→ OK。
⑥Multi-Plots:UtilityMenu >Plot >Multi-Plots。
(2)創(chuàng)建直線
①切換當(dāng)前活動(dòng)坐標(biāo)系到直角坐標(biāo)系:Utility Menu >WorkPlane >Change Active CS to >Global Cartesian →OK。
②在當(dāng)前活動(dòng)坐標(biāo)系下創(chuàng)建線:Main Menu >Preprocessor >Modeling>Create >Lines >Lines >In Active Coord →拾取K3和K4,拾取K4和K5,拾取K7和K8,拾取K8和K1 →OK。
(3)再創(chuàng)建圓弧線
①移動(dòng)工作平面:Utility Menu >WorkPlane >Offset WP to >Keypoints→拾取關(guān)鍵點(diǎn)K5和K7。
②創(chuàng)建局部坐標(biāo)系(柱坐標(biāo)系):Utility Menu >WorkPlane >Local Coordinate Systems >Create Local CS >At WP Origin →KCN:12;KCS:Cylindrical 1 →OK。
③切換當(dāng)前活動(dòng)坐標(biāo)系到局部坐標(biāo)系:UtilityMenu>WorkPlane>Change Active CS to>Specified Coord Sys → KCN:12 →OK。
④在當(dāng)前活動(dòng)坐標(biāo)系下創(chuàng)建線:Main Menu >Preprocessor >Modeling>Create >Lines >Lines >In Active Coord →拾取K5和K6 → Apply →拾取K6和K7 →OK。
(4)創(chuàng)建圓弧倒角:MainMenu >Preprocessor >Modeling >Create >Lines >Line Fillet→拾取線L5和L6 → OK →RAD:25 → OK。
3.創(chuàng)建面:
(1) 連線生成面:MainMenu >Preprocessor >Modeling >Create >Areas >Arbitrary >By Lines → 按順序拾取所有線 → OK。
(2)創(chuàng)建第1個(gè)圓孔面:MainMenu >Preprocessor >Modeling >Create >Areas >Circle >Solid Circle → Radius:6.25 →OK。
(2)創(chuàng)建第2個(gè)圓孔面:
①移動(dòng)工作平面:Utility Menu >WorkPlane >Offset WP to >Keypoints →拾取關(guān)鍵點(diǎn)K1和K3。
②創(chuàng)建圓孔面:MainMenu >Preprocessor >Modeling >Create >Areas >Circle >Solid Circle → Radius:6.25 →OK。
4.布爾操作面減面:MainMenu >Preprocessor >Modeling >Operate >Booleans >Subtract >Areas→ 拾取大面→ OK→ 拾取2個(gè)小面→ OK。
5.定義單元屬性
(1)定義單元類型:
①指定BEAM188單元:MainMenu >Preprocessor >Element Type >Add/Edit/Delete→Add→在左列表框中選擇Solid,在右列表框中選擇8 node 183 →OK。
②設(shè)置單元選項(xiàng):Options →K3:Plane strs w/thk →OK。帶厚度的平面應(yīng)力。
(2)定義實(shí)常數(shù)::MainMenu > Preprocessor > Real Constants > Add → Type 1 → OK → Real Constant Set No.:1;THK:3.125→ OK → Close。
(3)設(shè)置材料屬性:MainMenu > Preprocessor > Material Props > Material Models → Structural→ Linear → Elastic → Isotropic → EX:2e5;PRXY:0.3→ OK。
6.設(shè)置單元尺寸
(1)設(shè)置整體單元尺寸:MainMenu >Preprocessor >Meshing >MeshTool→在Size Controls下方選Global:Set →SIZE:10→OK。
(2)設(shè)置小圓孔線的單元份數(shù)
①選擇小圓孔線:UtilityMenu >Select >Entities→ 見(jiàn)下圖→OK。
②顯示線:UtilityMenu >Plot >Lines。
③小孔線份數(shù):MainMenu >Preprocessor >Meshing >MeshTool →在Size Controls下方選Lines:Set →Pick All →NDIV:4→OK。
(2)設(shè)置大圓弧線的單元份數(shù)
①選擇大圓弧線:UtilityMenu >Select >Entities→ 見(jiàn)下圖→OK。
②顯示線:UtilityMenu >Plot >Lines。
③小孔線份數(shù):MainMenu >Preprocessor >Meshing >MeshTool→在Size Controls下方選Lines:Set→Pick All→NDIV:6→OK。
7.劃分網(wǎng)格
(1)選擇所有:UtilityMenu >Select >Everything。
(2)顯示線:UtilityMenu >Plot >Lines。
(3)面劃分網(wǎng)格:MainMenu >Preprocessor >Meshing >MeshTool →Mesh →Pick All →OK。
(4)顯示線:UtilityMenu >Plot >Lines。
8.施加邊界條件
(1)施加約束:MainMenu >Solution >Define Loads >Apply >Structural >Displacement >On Lines→拾取線L3→OK → Lab2:ALL DOF→ OK。
(2)施加載荷:MainMenu >Preprocessor >Loads >Define Loads >Apply >Structural >Pressure >OnLines→ 拾取線L4→ OK → VALUE:2.601/3.125→ OK。均布載荷單位MPa。
(3)求解前保存模型:UtilityMenu > Files > Save as → 輸入file1.db→ OK。
6.求解
(1)求解:MainMenu > Solution > Solve > Current LS → File > Close → Solve Current Load Step → OK → Solution is done → Close。
(2)保存結(jié)果文件:UtilityMenu > Files > Save as → 輸入file2.db→ OK。
7.后處理
(1)變形云圖:MainMenu >General Postproc >Plot Results >Contour Plot >Nodal Solu →Nodal Solution → DOF Solution → 選擇各個(gè)方向的變形→OK。出圖并記錄x、y方向變形和總變形數(shù)值。
(2)應(yīng)力云圖:MainMenu >General Postproc >Plot Results >Contour Plot >Nodal Solu →Nodal Solution → Stress → von Mises stress → OK。出圖并記錄數(shù)據(jù)。
五、APDL步驟
/PREP7 !前處理器
K,1,50,0,0 !關(guān)鍵點(diǎn)
K,2,25,-25,0
K,3,0,0,0
K,4,0,250,0
K,5,250,250,0
K,6,250+25,250-25,0
K,7,250,250-50,0
K,8,50,250-50,0
KWPAVE,1,3 !移動(dòng)工作平面
CSWPLA,11,1,1,1, !創(chuàng)建局部柱坐標(biāo)系11
CSYS,11, !活動(dòng)坐標(biāo)系切換到局部柱坐標(biāo)系11
L,1,2 !生成圓弧線
L,2,3
/PNUM,KP,1 !打開(kāi)關(guān)鍵點(diǎn)編號(hào)
/PNUM,LINE,1 !打開(kāi)先編號(hào)
GPLOT
CSYS,0 !活動(dòng)坐標(biāo)系切換到轉(zhuǎn)角坐標(biāo)系
L,3,4 !生成直線
L,4,5
L,7,8
L,8,1
KWPAVE,5,7 !移動(dòng)工作平面
CSWPLA,12,1,1,1, !創(chuàng)建局部柱坐標(biāo)系12
CSYS,12, !活動(dòng)坐標(biāo)系切換到局部柱坐標(biāo)系12
L,5,6 !生成圓弧線
L,6,7
LFILLT,5,6,25, , !圓弧倒角
AL,ALL !由線生成面
CYL4, , ,6.25 !創(chuàng)建第1個(gè)圓孔面
KWPAVE,1,3 !移動(dòng)工作平面
CYL4, , ,6.25 !創(chuàng)建第2個(gè)圓孔面
ASBA,1,all !布爾操作,大面減去2個(gè)小面
ET,1,PLANE183 !單元類型
KEYOPT,1,3,3 !帶厚度
R,1,3.125, !實(shí)常數(shù),厚度
MP,EX,1,2e5 !材料,彈性模量
MP,PRXY,1,0.3 !材料,泊松比
ESIZE,10,0, !全局單元尺寸
LSEL,S,RADIUS,,6.25 !通過(guò)半徑選線
LPLOT !顯示線
LESIZE,all, , ,4, , , , ,1 !線的份數(shù)
LSEL,S,RADIUS,,25 !通過(guò)半徑選線
LPLOT !顯示線
LESIZE,all,6, , , , , , ,1 !線的份數(shù)
ALLSEL,ALL
LPLOT !顯示線
AMESH,all
DL,3, ,ALL, !施加約束
SFL,4,PRES,2.601/3.125, !施加壓力
FINISH
/SOL !求解器
SOLVE !求解
FINISH
/POST1 !后處理器
/UDOC,1,DATE,0 !關(guān)閉施加和ANSYS標(biāo)志
WPSTYLE,,,,,,,,0 !關(guān)閉工作平面標(biāo)志
/dev,font,1,Courier*New,400,0,-19,0,0,,, !字體
/GFORMAT,F,12,3, !保留3位小數(shù)點(diǎn)
PLNSOL, U,X, 0,1.0 !X方向變形云圖
PLNSOL, U,Y 0,1.0 !Y方向變形云圖
PLNSOL, U,SUM, 0,1.0 !總變形云圖
/GFORMAT,F,12,1, !保留1位小數(shù)點(diǎn)
PLNSOL, S,EQV, 0,1.0 !第四強(qiáng)度相當(dāng)應(yīng)力云圖
相關(guān)標(biāo)簽搜索：教育部CAE考試樣題-角架板變形和應(yīng)力ANSYS分析 Ansys有限元培訓(xùn) Ansys workbench培訓(xùn) ansys視頻教程 ansys workbench教程 ansys APDL經(jīng)典教程 ansys資料下載 ansys技術(shù)咨詢 ansys基礎(chǔ)知識(shí) ansys代做 Fluent、CFX流體分析 HFSS電磁分析 Abaqus培訓(xùn)
