[原創(chuàng)]教育部CAE考試ANSYS分析樣題-直角拐變形和應力計算

2017-02-24  by:CAE仿真在線  來源:互聯(lián)網

導讀:掌握空間梁結構的建模過程,熟練進行后處理(反力列表、內力圖、應力云圖和變形云圖),約束反力和變形是在整體坐標系下輸出的,內力和應力是在梁單元的單元坐標系下輸出的。

---

一、問題描述

直角拐的AB 桿與 AC 軸剛性連接,A為軸承,允許 AC 軸的A 端截面在軸承內轉動,但不能移動。已知 P =60 N,E=210 GPa,μ =0.25,圖中長度單位:mm。計算B點的垂直位移和扭轉角,AB桿彎曲產生的正應力,AC桿扭轉產生的切應力。樣題來源:網絡。

問題分析:AB桿產生彎曲變形,AC桿產生扭轉變形,用梁單元BEAM188建模分析。梁單元的單元屬性有單元類型、截面屬性和材料屬性。ANSYS無單位,需自己統(tǒng)一,本次采用N、mm和MPa單位制,力矩是N.mm。A、B和C點的坐標分別取關鍵點1(500,0,0),關鍵點2(500,0,-300),關鍵點3(0,0,0)。A和B連線為線1,A和C連線為線2。單元尺寸取10mm。

計算結果匯總

B點鉛垂位移:-8.227 mm

B點扭轉角:-0.038 rad

AB桿彎曲正應力:216 MPa

AC桿扭轉切應力:11.5 MPa

(1)撓度云圖,B點鉛垂位移-8.227mm。

(2)轉角云圖,B點扭轉角-0.038rad。

(3)彎曲正應力云圖,最大數(shù)值在AB桿的B點上下兩側,216MPa。

(4)扭轉切應力云圖,最大數(shù)值在AC桿的整個圓周表面,11.5MPa。

二、GUI步驟

1.進入ANSYS

程序→ ANSYS → ANSYS Product Launcher → 改變working directory到指定文件夾→ 在job name輸入:file → Run。

2.定義單元屬性

(1)定義單元類型:

①指定BEAM188單元:MainMenu >Preprocessor >Element Type >Add/Edit/Delete →Add →在左列表框中選擇Beam,在右列表框中選擇2 node 188 →OK。

②設置單元選項:Options →Elementbehavior K3:Cubic Form(三次形函數(shù)) →OK。默認情況下Element behavior是一次形函數(shù),為了提高計算精度和減少單元個數(shù),改成三次形函數(shù)。低版本只有一次和二次形函數(shù),高版本增加了三次形函數(shù)。

(2)定義截面:

①AB截面:MainMenu >Preprocessor >Sections >Beam >Common Sections →ID:1;Sub-Type:矩形截面;B:10;H:5;Nb:0;Nh:0→Meshview →OK。ID為截面編號。

默認情況下高度為H,寬度為B,高度沿坐標系的Z方向。想要本例高度沿Y方向,將B和H的數(shù)值交換一下即可。

②AC截面:MainMenu >Preprocessor >Sections >Beam >Common Sections →ID:2;Sub-Type:圓形截面;R:10;N:0;T:0→Meshview →OK。

(3)設置材料屬性:MainMenu > Preprocessor > Material Props > Material Models → Structural→ Linear → Elastic → Isotropic → EX:2.1E5;PRXY:0.25→ OK。

3.建立幾何模型

(1)調整視圖:選擇窗口右側的按鈕。

(2)生成關鍵點:Main Menu >Preprocessor >Modeling >Create >Keypoints >In Active CS →依次輸入關鍵點的編號和坐標:1 (500,0,0),2 (500,0,-300),3 (0,0,0) →OK。

(3)創(chuàng)建直線:MainMenu >Preprocessor >Modeling >Create >Lines >Lines >Straight Line →依次拾取1和2,1和3 →OK。

(4)打開關鍵點和線編號:Utility Menu > PlotCtrls > Numbering→KP Keypoint numbers:ON,LINE Line numbers:ON→ OK。

4.劃分網格

(1)設置線的單元屬性:

①設置AB桿的截面屬性:MainMenu >Preprocessor >Meshing >Mesh Tool →在Element Attributes下方選擇Lines Set→ 拾取線L1→OK →選擇MAT:1,TYPE:1,SECT:1→OK。

②設置AC桿的截面屬性:MainMenu >Preprocessor >Meshing >Mesh Tool →在ElementAttributes下方選擇LinesSet→ 拾取線L2→OK →選擇MAT:1,TYPE:1,SECT:2→OK。

(2)設置單元尺寸:MainMenu >Preprocessor >Meshing >Mesh Tool →在Size Controls下方選擇Global Set →SIZE:10→OK。每10mm劃分一個單元。

(3)劃分梁單元:MainMenu >Preprocessor >Meshing >Mesh Tool →Mesh:Lines→ Mesh → Pick All。

(4)打開梁單元的單元形狀:Utility Menu >PlotCtrls>Style >Size and Shape →[/ESHAPE]: On。

(5)顯示單元:Utility Menu > Plot > Element。

5.施加邊界條件

(1)施加約束:MainMenu>Solution>Define Loads>Apply>Structural>Displacement>OnKeypoints →拾取關鍵點K1→OK → Lab2:UY和UZ→ Apply →拾取關鍵點K3→ OK → Lab2:ALL→ OK。

(2)施加載荷:MainMenu >Solution >Define Loads >Apply >Structural >Force/Moment >OnKeypoints → 拾取關鍵點K2→ OK → Lab:FY,VALUE:-60 →OK。

(3)求解前保存模型:UtilityMenu > Files > Save as → 輸入file1.db→ OK。

6.求解

(1)求解:MainMenu > Solution > Solve > Current LS → File > Close → Solve CurrentLoad Step → OK → Solution is done → Close。

(2)保存結果文件:UtilityMenu > Files > Save as → 輸入file2.db→ OK。

7.后處理

(1)彎曲變形(撓度和轉角)

①撓度云圖:UtilityMenu >Plot >Results >Contour Plot >Nodal Solution → Y - Component of displacement→OK。出圖并記錄數(shù)據。

②轉角云圖:UtilityMenu >Plot >Results >Contour Plot >Nodal Solution → X - Component of rotation→OK。出圖并記錄數(shù)據。

(2)應力云圖(切應力和正應力)

①扭轉切應力云圖:MainMenu >General Postproc >Plot Results >Contour Plot >Nodal Solu → XY Shear stress → OK。出圖并記錄數(shù)據。

②正應力云圖:MainMenu >General Postproc >Plot Results >Contour Plot >Nodal Solu →X-Component stress → OK。出圖并記錄數(shù)據。

(3)列表查看約束反力:

①MainMenu > General Postproc > List Results > Reaction Solu → All strucforc F → OK。

②MainMenu > General Postproc > List Results > Reaction Solu → All struc mome M → OK。

記錄數(shù)據,體會反力為什么是這個方向。節(jié)點1是A點的反力,節(jié)點12是C點反力。

(4)查找定義內力(剪力、彎矩和扭矩)單元表的方法

①打開梁單元的單元坐標系:UtilityMenu >PlotCtrls >Symbols →ESYS:On→OK。

②檢查梁單元的單元坐標系,看不清請把單元形狀關掉,檢查后再把單元形狀打開。單元坐標系的X、Y和Z坐標的顏色與整體坐標系相同。內力輸出是在梁單元的單元坐標系下輸出的。可以判斷出,AB段的剪力是FY,AB段的彎矩是MZ,AC段的扭矩是MX。

③打開梁單元的單元坐標系:UtilityMenu>PlotCtrls>Symbols →ESYS:Off→OK。

④查找定義BEAM188內力單元表的方法:打開ANSYS Help,搜索BEAM188。

A.找到BEAM188的單元介紹頁面后,頁面中查表Table188.1: BEAM188 Element Output Definitions。

表中查找Name:SF:y,z,Definition:Section shear forces,在Name欄中SFy便是剪力。

表中查找Name:My,Mz,Definition:Bending moments,在Name欄中MZ便是彎矩。

表中查找Name:TQ,Definition:Torsional moment,在Name欄中TQ便是扭矩。

B.頁面中查表Table188.2: BEAM188 Item and Sequence Numbers。表中查找Output Quantity Name,Item,I,J對應的代號。

Table188.2: BEAM188 Item and Sequence Numbers

Output Quantity Name	ETABLE and ESOL Command Input
	Item	E	I	J
Fx-軸力	SMISC	--	1	14
My-彎矩	SMISC	--	2	15
Mz-彎矩	SMISC	--	3	16
TQ-扭矩	SMISC	--	4	17
SFz-剪力	SMISC	--	5	18
SFy-剪力	SMISC	--	6	19

(3)剪力圖

①定義剪力單元表:MainMenu > General Postproc > Element Table > Define Table → Lab:輸入SFY_I→ Item:選擇Bysequence num → Comb:選擇SMISC,在SMISC后面輸入“6” →OK → Apply → Lab:輸入SFY_J→ Item:選擇By sequence num → Comb:選擇SMISC,在SMISC后面輸入“19”→ OK → Close。

②剪力云圖:MainMenu > General Postproc > Plot Results > Contour Plot > Line ElemRes → LabI選擇SFY_I,LabJ選擇SFY_J→ OK。

③剪力列表:MainMenu > General Postproc > Element Table > List Element Table → 選擇SFY_I和SFY_J→ OK → 記錄彎矩值→ File → Close。

(4)彎矩圖

①定義彎矩單元表:MainMenu > General Postproc > Element Table > Define Table → Lab:輸入MZ_I→ Item:選擇Bysequence num → Comb:選擇SMISC,在SMISC后面輸入“3” →OK → Apply → Lab:輸入MZ_J→ Item:選擇Bysequence num → Comb:選擇SMISC,在SMISC后面輸入“16”→ OK → Close。

②彎矩云圖:MainMenu > General Postproc > Plot Results > Contour Plot > Line ElemRes → LabI選擇MZ_I,LabJ選擇MZ_J→ OK。

③將彎矩單位N.mm轉換成N.m:Main Menu >General Postproc >Element Table>Add Items → LabR:MZ_I,FACT1:1e-3,Lab1:MZ_I → Apply → LabR:MZ_J,FACT1:1e-3,Lab1:MZ_J → OK。

④重新畫彎矩云圖:MainMenu > General Postproc > Plot Results > Contour Plot > Line ElemRes → LabI選擇MZ_I,LabJ選擇MZ_J→ OK。單位N.m。

⑤彎矩列表:MainMenu > General Postproc > Element Table > List Element Table → 選擇MZ_I和MZ_J→ OK → 記錄彎矩值→ File → Close。

(4)扭矩圖

①定義扭矩單元表:MainMenu > General Postproc > Element Table > Define Table → Lab:輸入TQ_I→ Item:選擇Bysequence num → Comb:選擇SMISC,在SMISC后面輸入“4” → OK→ Apply → Lab:輸入TQ_J→ Item:選擇Bysequence num → Comb:選擇SMISC,在SMISC后面輸入“17” →OK → Close。

②扭矩云圖:MainMenu > General Postproc > Plot Results > Contour Plot > Line ElemRes → LabI選擇TQ_I,LabJ選擇TQ_J→ OK。

③將扭矩單位N.mm轉換成N.m:Main Menu >General Postproc >Element Table>Add Items → LabR:TQ_I,FACT1:1e-3,Lab1:TQ_I → Apply → LabR:TQ_J,FACT1:1e-3,Lab1:TQ_J → OK。

④重新畫扭矩云圖:MainMenu > General Postproc > Plot Results > Contour Plot > Line ElemRes → LabI選擇TQ_I,LabJ選擇TQ_J→ OK。單位N.m。

⑤扭矩列表:MainMenu > General Postproc > Element Table > List Element Table → 選擇TQ_I和TQ_J→ OK → 記錄扭矩值→ File → Close。

8.退出ANSYS軟件

Utility Menu> File > Exit → Quit-No Save → OK。

五、APDL步驟

FINISH

/CLEAR,NOSTART

/PREP7

ET,1,BEAM188 !單元類型

KEYOPT,1,3,2 !形函數(shù)

KEYOPT,1,4,2 !包含扭轉和彎曲的切應力

MP,EX,1,2.1e5 !材料屬性MPa

MP,PRXY,1,0.25

SECTYPE, 1, BEAM, RECT, ,0 !AB截面屬性mm

SECOFFSET, CENT

SECDATA,10,5,0,0,0,0,0,0,0,0,0,0

SECTYPE, 2, BEAM, CSOLID, ,0 !AC截面屬性mm

SECOFFSET, CENT

SECDATA,10,0,0,0,0,0,0,0,0,0,0,0

/VIEW,1,1,1,1 !視圖

K,1,500,0,0, !創(chuàng)建關鍵點mm

K,2,500,0,-300,

K,3,0,0,0,

L,1,2 !創(chuàng)建線

L,1,3

/PNUM,KP,1 !關鍵點編號

/PNUM,LINE,1 !線編號

LSEL,S , , , 1

LATT,1, ,1, , , ,1

LSEL,S, , , 2

LATT,1, ,1, , , ,2

ALLSEL,ALL

LESIZE,ALL, , ,10, , , , ,1 !單元尺寸mm

LMESH,ALL !線分網

/ESHAPE,1.0 !單元形狀

DK,1,UY !A點約束

DK,1,UZ

DK,3,ALL !C點約束

FK,2,FY,-60 !B點集中力

FINISH

/SOLU

SOLVE !求解

FINISH

/POST1

/UDOC,1,DATE,1 !關閉ANSYS標志和時間

/dev,font,1,Courier*New,400,0,-21,0,0,,, !3號字體

/GFORMAT,F,12,3, !數(shù)據格式

PLNSOL, U,Y, 0,1.0 !撓度

PLNSOL, ROT,X, 0,1.0 !彎曲角rad

/GFORMAT,F,12,1, !數(shù)據格式

PLNSOL, S,X, 0,1.0 !彎曲正應力

PLNSOL, S,XY, 0,1.0 !扭轉切應力

PRRSOL,F !約束反力列表

ETABLE,SFY_I,SMISC, 6 !定義剪力單元表

ETABLE,SFY_J,SMISC, 19

/VIEW,1,1 !視圖

PLLS,SFY_I,SFY_J,1,0 !剪力圖云圖

PRETAB,SFY_I,SFY_J !剪力列表

ETABLE,MZ_I,SMISC, 3 !定義彎矩單元表

ETABLE,MZ_J,SMISC, 16

PLLS,MZ_I,MZ_J,1,0 !彎矩圖云圖N.mm

SADD,MZ_I,MZ_I, ,1E-3,1, , !將彎矩單位N.mm轉換成N.m

SADD,MZ_J,MZ_J, ,1E-3,1, ,

PRETAB,MZ_I,MZ_J !彎矩列表N.m

PLLS,MZ_I,MZ_J,1,0 !彎矩圖云圖N.m

ETABLE,TQ_I,SMISC, 4 !定義扭矩單元表

ETABLE,TQ_J,SMISC, 17

/VIEW,1,,,1 !視圖

PLLS,TQ_I,TQ_J,1,0 !扭矩圖云圖N.mm

SADD,TQ_I,TQ_I, ,1E-3,1, , !將扭矩單位N.mm轉換成N.m

SADD,TQ_J,TQ_J, ,1E-3,1, ,

PRETAB,TQ_I,TQ_J !扭矩列表N.m

PLLS,TQ_I,TQ_J,1,0 !扭矩圖云圖N.m

相關標簽搜索：[原創(chuàng)]教育部CAE考試ANSYS分析樣題-直角拐變形和應力計算 Ansys有限元培訓 Ansys workbench培訓 ansys視頻教程 ansys workbench教程 ansys APDL經典教程 ansys資料下載 ansys技術咨詢 ansys基礎知識 ansys代做 Fluent、CFX流體分析 HFSS電磁分析 Abaqus培訓