例1 簡(jiǎn)支梁-ANSYS模態(tài)分析及結(jié)果輸出

2017-01-16 by:CAE仿真在線(xiàn) 來(lái)源:互聯(lián)網(wǎng)

/FILNAME,Simple Beam,0
/CWD,'F:\AnsysGlobalMatrix'
/TITLE,Simple Beam
/PREP7
!截面積
AREA = 1.67e-3
!慣性矩
IZZ = 1.6652e-6
!高度
H = SQRT(12*IZZ/AREA)
!計(jì)算模態(tài)數(shù)
MN =6
!總結(jié)點(diǎn)數(shù)
NOD_N =6
!單元結(jié)點(diǎn)自由度
DOF = 3
!單元
ET,1,BEAM3
!實(shí)常數(shù)
R,1,AREA,IZZ,H
!定義材料
MP,DENS,1,7850
MP,EX,1,2E11
MP,PRXY,1,0.3
!建立節(jié)點(diǎn)
CSYS0
*DO,I,1,NOD_N
N,I,0.5*(I-1),0,0,
*ENDDO
!建立單元
*DO,I,1,NOD_N-1
!單元類(lèi)型
TYPE,1
!單元材料
MAT,1
!單元實(shí)常數(shù)
REAL,1
ESYS,0
!建單元
E,I,I+1
*ENDDO
/SOLVE
!模態(tài)分析
ANTYPE,2
!朗茲法計(jì)算MN階振型,并關(guān)于質(zhì)量矩陣歸一化
MODOPT,LANB,MN,0,0, ,OFF
EQSLV,SPAR
MXPAND,MN

!約束
D,1, , , , , ,UX,UY
D,6,UY

!求解
SOLVE
/POST1
!模態(tài)列表顯示
SET,LIST

*DIM,FREQ_HZ,ARRAY,1,MN
*DO,I,1,MN
*GET,FREQ_HZ(1,I),MODE,I,FREQ
*ENDDO

*MWRITE,FREQ_HZ,FREQ,TXT, ,IJK,1,MN, ,
(F10.4)

*DIM,MODE,ARRAY,NOD_N,DOF
*DIM,NAME,CHAR,10,1
NAME(1) = 'MOD01','MOD02','MOD03','MOD04','MOD05','MOD06','MOD07','MOD08','MOD09','MOD10'
SET,FIRST
*DO,K,1,MN
*DO,I,1,NOD_N
*GET,MODE(I,1),NODE,I,U,X
*GET,MODE(I,2),NODE,I,U,Y
*GET,MODE(I,3),NODE,I,ROT,Z
*ENDDO
*MWRITE,MODE,NAME(K),TXT, ,JI,DOF,NOD_N
(1E20.8)
SET,NEXT
*ENDDO
FINISH
/AUX2
FILE,'ContinuousBeam','full',' '
HBMAT,'stiffness',' ',' ',ASCII,STIFF,YEs
HBMAT,'mass',' ',' ',ASCII,MASS,YES

開(kāi)放分享：優(yōu)質(zhì)有限元技術(shù)文章,助你自學(xué)成才